Ticket #141: turbo-plus.patch

Source/CommandLine.cobra

@@ -1269 +1269 @@
         if options.getDefault('debug', '') not in ['', '0', '-'] and not options.isSpecified('debugging-tips')
             options['debugging-tips'] = false
         if options.boolValue('turbo')
-            options['contracts'] = 'none'
-            options['include-asserts'] = false
-            options['include-nil-checks'] = false
-            options['include-tests'] = false
-            options['include-traces'] = false
-            options['optimize'] = true
+            if not options.isSpecified('contracts')
+                options['contracts'] = 'none'
+            if not options.isSpecified('include-asserts')
+                options['include-asserts'] = false
+            if not options.isSpecified('include-nil-checks')
+                options['include-nil-checks'] = false
+            if not options.isSpecified('include-tests')
+                options['include-tests'] = false
+            if not options.isSpecified('include-traces')
+                options['include-traces'] = false
+            if not options.isSpecified('optimize')
+                options['optimize'] = true
             
     def _interpretValue(valueStr as String, spec as OptionSpec) as dynamic?
         value as dynamic?

Tests/700-command-line/603-turbo-plus.cobra

@@ +1 @@
+# test -turbo with one of suboptions overidden
+
+use System.Diagnostics
+
+class Test
+
+    def main is shared
+        Test().run
+
+    def run
+        sub = '603a-sub.cobra'
+        ite  = '-include-tests:yes'
+        itr  = '-include-traces:yes'
+        ia   = '-include-asserts:yes'
+
+        output = .runCobraExe('-turbo [sub]')
+        try
+            assert '** Test' not in output
+            assert 'trace:' not in output
+            assert 'AssertException' not in output
+            assert 'OKThxBai' in output
+        success
+            print '-turbo OK'
+
+        output = .runCobraExe('-turbo [ite] [sub]')
+        try
+            assert '** Test' in output
+            assert 'trace:' not in output
+            assert 'AssertException' not in output
+            assert 'OKThxBai' in output
+        success
+            print '-turbo [ite] OK'
+            
+        output = .runCobraExe('-turbo [itr] [sub]')
+        try
+            assert '** Test' not in output
+            assert 'trace: a=99;'  in output
+            assert 'AssertException' not in output
+            assert 'OKThxBai' in output
+        success
+            print '-turbo [itr] OK'
+        
+        output = .runCobraExe('-turbo [ia] [sub]')
+        try
+            assert '** Test' not in output
+            assert 'trace:'  not in output
+            assert 'AssertException thrown' in output
+            assert 'OKThxBai' in output
+        success
+            print '-turbo [ia] OK'
+        
+        output = .runCobraExe('-turbo [ia] [itr] [ite] [sub]')
+        try
+            assert '** Test' in output
+            assert 'trace:'  in output
+            assert 'AssertException thrown' in output
+            assert 'OKThxBai' in output
+        success
+            print '-turbo [ia] [itr] [ite]  OK'
+            
+    def runCobraExe(args as String) as String
+        p as System.Diagnostics.Process?
+        return CobraCore.runCobraExe(args, out p)

Tests/700-command-line/603a-sub.cobra

@@ +1 @@
+# .skip.
+# executed by 603-turbo-plus
+class Test
+    def main is shared
+        test
+            print '** Test'
+        body
+            a = 99
+            trace a
+            print 'OKThxBai'
+            try
+                assert a == 100
+            catch AssertException   
+                print 'AssertException thrown'

Developer/IntermediateReleaseNotes.text

@@ -392 +392 @@
 * Fixed: Cobra gives an inscrutable error message for numeric for-loops that have incompatible numeric types. ticket:165
 
 * Fixed: Improper codegen for static constructors. ticket:169
+
+* Fixed: Cannot effectively put more options after -turbo. ticket:141