Ticket #200: options-file.patch

Source/cobra.cobrarc

@@ +1 @@
+# = Cobra compiler options file for building compiler =
+# make a copy of the compiler exe to do the compile (wdws wont allow overwrite of a running exe file)
+#   cp cobra.exe cobraOld.exe
+# 1) copy this file to .cobrarc 
+#   cp cobra.cobrarc .cobrarc
+# and run compiler as follows
+#   ./cobraOld cobra.cobra
+# 2) or just run run compiler as follows
+#   ./cobraOld -optfile:cobra.cobrarc cobra.cobra
+# --------------------------------------------------
+
+#compile Only (do not run the code post compilation )
+compile:true
+
+#Colorize any error messages and the messages "Compilation failed" and 
+# "Compilation succeeded" (as red, red and blue). default is false
+color:true
+
+#Embed the Cobra run-time support code in the assembly
+embed-run-time:true
+
+#Turn on generation of system debugging information. 
+# full enables attaching a debugger to a running program. 
+# Turning on implies -debugging-tips:no.  Default is 0
+debug:1
+#debug:pdbonly
+#debug:full
+
+#Emit the total duration (wall time) of this run of cobra 
+#  (including the target program, if it is to be run). 
+#Default is false.
+#timeit:true
+
+# file containing filenames for Cobra to process
+#  One file per line; # comments and blank lines are ignored.
+files:files-to-compile.text
+
+# Initial filename(s) list 
+cobra.cobra

Source/.cobrarc

@@ +1 @@
+# = Cobra compiler template options file = 
+# This file is read and processed for compiler options before any commandline options are processed
+# Any specified commandline options will override any active settings made in this file
+#----------------------------------------------------------------------------------------
+
+#Specify to only compile (do not run the code post compilation )
+#compile:true
+
+#Compile sources if any source file is newer than the existing output file 
+# (or there is no output file). default is false
+#compile-if-needed:true
+
+#Specify form of code generation for contracts.
+# choices: 'none', 'inline', 'methods'. 
+#Default is 'inline'. none suppresses contracts code entirely
+#contracts:none
+#contracts:methods
+
+#Turn on generation of system debugging information. 
+# full enables attaching a debugger to a running program. 
+# Turning on implies -debugging-tips:no.  Default is 0
+#debug:0
+#debug:1
+#debug:pdbonly
+#debug:full
+
+#Say to embed the Cobra run-time support code in the assembly so that no reference to an 
+#  external Cobra.Lang.dll is required. Adds approximately 85KB - 130KB overhead depending on 
+#  other options such as -include-asserts or -turbo
+#  default is false
+#embed-run-time:true
+
+#Include code for assert statements in the program. Default is true
+#include-asserts:false
+
+#Include checks on non-nilable class variables, method arguments and "to !" casts. 
+# Default is true
+#include-nil-checks:false
+
+#Include unit tests for classes and members in the output assembly. Default is true
+#include-tests:false
+
+#Include trace statements in the output assembly. Default is true
+#include-traces:false
+
+#When a class does not provide initializers, Cobra will mirror each initializer in the base class. 
+# The old behavior was to provide one parameterless initializer. 
+# Use this option to switch to the old behavior.
+#legacy-one-default-initializer:true
+
+#Specify additional directories to search in for references. 
+# Maps to -lib: on .NET and -classpath on JVM
+#library-directory:PATH
+#library-directory:PATH2
+
+#Specify the name of the type containing the "main" method
+#main:TYPENAME  
+
+#Set the namespace for all Cobra source files as if each one started with "namespace <name>". 
+#Can be a qualified name.
+#namespace:My.Name.Space
+
+# Set the real numeric type for both the 'number' type and fractional literals such as '1.0'.
+# choices are decimal, float, float32, float64.    Default is decimal
+#number:float
+#number:float64
+
+#Enable optimizations. Default is false
+#optimize:true
+
+# Specify a file containing filenames for Cobra to process
+#  One file per line; # comments and blank lines are ignored.
+#files:FILENAME
+
+#Specify the output file name (default: base name of first file).
+# -test overrides this with a temporary program that runs only the unit tests and is then removed afterwards.',
+#out:FILENAME
+
+#Reference package via "pkg-config --libs". (Mono only.)
+#pkg:NAME
+
+#Specify a DLL to reference to resolve imports ('use' clause) in the sourcefiles
+#reference:DLL-NAME
+#reference:DLL-NAME2
+
+#Provide commandline args to be passed to the built executable, 
+# Supports single or dbl quoting to preserve whitespace
+#run-args: args to pass to cmdline of built exe
+#run-args:'test args' to pass to cmdline of "built exe" file.
+
+#Build a specific target type
+# choices are exe, winexe, lib and module, Default is exe
+# specific to .Net
+#target:exe
+#target:winexe
+#target:lib
+
+#Emit the total duration (wall time) of running cobra 
+#  (including the target program, if it is to be run). 
+#Default is false.
+#timeit:true
+
+# Compile for Maximum run-time performance. 
+# This is a convenience for contracts:none include-asserts:no include-nil-checks:no include-tests:no include-traces:no optimize
+#turbo:true
+
+#Enable extra output from Cobra. Mostly useful for debugging Cobra and reporting problems. Values 0 - 5.
+# Warning: Level 5 causes megabytes of output.',
+#verbosity:1
+#verbosity:2
+
+#Enable extra output from Cobra regarding the resolution of references to libraries. 
+#Mostly useful for debugging Cobra and reporting problems. Values 0 - 5.',
+#verbosity-ref:2
+
+#------------------------
+
+#Colorizes any error messages and the messages "Compilation failed" and 
+# "Compilation succeeded" (as red, red and blue). default is false
+#color:true
+
+#Rewrite source files with corrections, only when unambiguous. 
+#For example, "string" --> "String". Default is 'none'
+#correct-source:none
+#correct-source:case
+#correct-source:all
+
+#Specify an editor and command line options to invoke if there is a compile-time error. 
+#Use underscore (_) for space in the specification. Can also set via COBRA_EDITOR environment variable (in which case spaces work fine).',
+#editor:me_-l_LINE_FILE
+#editor:uedit32_FILE/LINE
+#editor:mate_FILE_-l_LINE
+
+#------------------------
+
+#Display debugging tips when an unhandled exception occurs. Overridden by -exception-report.
+#  Default is yes
+#debugging-tips:no
+
+# Enable a detailed stack trace which gives postmortem information for uncaught exceptions,
+#  but slows execution. Works in combination with -exception-report
+#detailed-stack-trace:true
+
+#Turn on an informative HTML report that will be generated if the program throws an uncaught exception. 
+# default is false
+#exception-report:true
+
+#Specify to output the command line in HTML
+#output-html:true
+
+#------------------------
+
+#Keep any intermediate files that Cobra generates, which are normally deleted. 
+# Example intermediate files are *.cobra.cs.  Default is false
+#keep-intermediate-files:true
+
+#Specify the back-end of the compiler, possibly different than the build platform. Used for cross-compilation.
+#back-end:clr
+#back-end:jvm
+
+#Specify the path to the back-end native compiler. 
+#This can be an executable (such as csc.exe or javac), a library (such as Cobra.Sharp.dll), 
+#  "auto" or "provider".  Default is 'auto'
+#native-compiler:path/to/native-compiler
+
+#Pass additional arguments to the native back-end compiler (such as C# or Java)
+#native-compiler-args:ARGS
+
+#Tell cobra compiler to build the standard library
+#build-standard-library:true
+
+#Specify the method to invoke to run the unit tests. The method must be "shared". 
+# Typically the method will make use of classes in Cobra.Lang.Test to set up and initiate the test run.
+# default is Cobra.Lang.CobraCore.runAllTests
+#test-runner:QUALIFIED-METHOD-NAME|nil
+
+#------------------------
+
+#Delay-sign the assembly using only the public portion of the strong name key
+# specific to .Net only
+#delay-sign:true
+
+#Specify a strong name key container used to strongname the output assembly
+# specific to .Net only
+#key-container:FILENAME
+
+#Specify a strong name key file used to sign the output assembly
+# specific to .Net only
+#key-file:FILENAME
+

Source/CommandLine.cobra

@@ -343 +343 @@
             'description': "Set the real numeric type for both the 'number' type and fractional literals such as '1.0'.",
         },
         {
+            'name': 'options-file',
+            'synonyms': ['optfile', 'of'],
+            'isAccumulator': true,
+            'description': 'Name an options file to read cmdline options from. Specify "none" to suppress default probe for first of ".cobrarc", "cobra.rc", "cobra.init"',
+            'args': 'filename',
+        },
+        {
             'name': 'optimize',
             'synonyms': ['o'],
             'type': 'bool',
@@ -562 +569 @@
             .error(ape.message)
         _verbosity = _argParser.verbosity
         CobraMain.willTimeIt = _argParser.willTimeIt
-        
+    
+    def parseOptFile
+        """
+        Load OptionValues obtained from reading a cwd options file into _options
+        """
+        defaultOptFiles = ['.cobrarc', 'cobra.rc', 'cobra.init']
+        optFiles = _options.getDefault('options-file', defaultOptFiles ) to List<of String>
+        if optFiles[0] == 'none'
+            return # suppress reading any (or default) optionsFile
+        paths = List<of String>()
+        try
+            fileOptions = _argParser.parseOptionsFile(optFiles, inout paths)
+        catch ape as ArgParseException
+            fileOptions = OptionValues()
+            .error(ape.message)
+        _verbosity = _argParser.verbosity
+        CobraMain.willTimeIt = _argParser.willTimeIt
+        # merge in fileOptions values unless have one from cmdline setting
+        _options.combineNew(fileOptions)
+        if paths.count  # if paths from optionsfile, append after any from cmdline
+            _pathList.addRange(paths)
+            
     def run
         """
         Run the command line using the command line arguments.
@@ -578 +606 @@
             .doAbout
             return
         .parseArgs(args)
-
+        .parseOptFile
+        
         if _options.boolValue('output-html')
             _htmlWriter = HtmlWriter(Console.out)
             dest = _htmlWriter to TextWriter
@@ -763 +792 @@
     
         exeFileName as String? = nil
         runArgs = .options.getStringList('run-args')
-        # TODO: what's this?
-        # exeArgs = .options.getDefaultLOStr('exe-args')
-        # if exeArgs.count
-        #   exeFileName = exeArgs[0]
-        #   runArgs = exeArgs[1:]
         p = c.runProcess(exeFileName, runArgs)
         if _verbosity >= 1
             print 'Running: [p.startInfo.fileName] [p.startInfo.arguments]'
@@ -1013 +1037 @@
         paths = List<of String>()
         # TODO: mark which opts as unusable in this context and filter out
         _optsOnly = true
-        .parseArgs(args, out opts, out paths)
+        if args.count
+            .parseArgs(args, out opts, out paths)
         if .verbosity or opts.getDefault('verbosity', 0) to int
             print 'parseToOptions Option Dictionary:'
             opts.print
         return opts
         
+    def parseFileOptions(args as IList<of String>, paths as inout List<of String> ) as OptionValues
+        """
+        Reuse ArgParser to parse string option args and filenames read from optionsfile. 
+        Return new set of Options and paths from given args list
+        """
+        opts = OptionValues()
+        _optsOnly = false # allow filenames in optionsfile
+        if args.count
+            .parseArgs(args, out opts, out paths)
+        if .verbosity or opts.getDefault('verbosity', 0) to int
+            print 'parseFileOptions Option Dictionary:'
+            opts.print
+        return opts
+
     def parseArgs(args as IList<of String>, options as out OptionValues?, paths as out List<of String>?)
         """
         Parse command line arguments: options and files.
@@ -1092 +1131 @@
                 _error('Cannot have these main options at the same time: [mainOptions.join(", ")]')
 
             _unpackOptions(valueDict, fileList) 
-
+            
             # set the out parameters
             options = OptionValues(valueDict)
             options.setSpecified(didSpecify)
@@ -1361 +1400 @@
     def _error(msg as String)
         throw ArgParseException(msg)
 
+        
+    def parseOptionsFile(optFiles as IList<of String>, paths as inout List<of String>) as OptionValues
+        """
+        Find first existing OptionsFile from given list of names, read its contents and 
+        process to an OptionValues object.
+        """
+        args = List<of String>()
+        runArgs = ''
+        #print 'optionFilesList = [optFiles]'
+        for fileName in optFiles
+            if  not File.exists(fileName), continue
+            #print 'Processing optionsFile [fileName]...'
+            try
+                for line in File.readAllLines(fileName)
+                    line = line.trim
+                    if line.length==0 or line.startsWith('#'), continue
+                    if _verbosity, print '[fileName]: [line]'
+                    if line.startsWith('run-args:')
+                        runArgs = line[9:]
+                        continue
+                    if not line[0] == '-' and ':' in line  # looks like optionkey:value pair
+                        line = '-' + line
+                    args.add(line)
+            catch IOException
+                print 'Cannot open optionsFile "[fileName]".'
+            break   # do first file found only  
+        if runArgs.length
+            args.add('-run-args')
+            args.addRange(.cmdLineSplit(runArgs)) 
+        options = .parseFileOptions(args, inout paths)
+        return options      
 
-
+    def cmdLineSplit(line as String) as List<of String>
+        """
+        Split line into tokens same as a cmdline tokeniser.
+        Break into words on whitespace preserving single or double quoted 
+        sequences but removing the quotes.
+        """
+        #TODO: move into utils
+        words=List<of String>()
+        word = StringBuilder()
+        inStringSingle = inStringDouble = false
+        for c in line
+            if c in [c' ', c'\t'] and not (inStringSingle or inStringDouble)
+                if word.length
+                    words.add(word.toString)
+                    word.remove(0,word.length)
+                continue    
+            if c == c'"' and not inStringSingle 
+                inStringDouble = not inStringDouble
+                continue
+            if c == c"'" and not inStringDouble 
+                inStringSingle = not inStringSingle
+                continue
+            word.append(c)
+        if word.length
+            words.add(word.toString)
+        return words        
+        
 class HtmlWriter
     inherits TextWriter
     """

Source/CobraParser.cobra

@@ -2396 +2396 @@
         return ThrowStmt(token, expr)
 
     def tryStmt as Stmt
-        # try... except... success... finally...
+        # try... catch... success... finally...
         token = .expect('TRY')
         tryBlock = .block
         catchBlocks = List<of CatchBlock>()

Tests/700-command-line/optFile/520-debug.cobra

@@ +1 @@
+# .skip. driven from 520-debugTest.cobra using args -debug
+
+# This test covers:
+# * That Cobra executables have the correct filname and line number embedded in them (see SharpWriter.cobra)
+# * That passing -debug to cobra results in stack traces that have file name and line number information.
+# * On Mono, that passing -debug to cobra also passes --debug to mono when running the program.
+
+
+# non-debug stack trace:   at Test.Main () [0x00000] 
+# debug stack trace:   at Test.Main () [0x00022] in /Users/chuck/Projects/Cobra/Workspace-Misc/Source/foo.cobra:5
+#                or:   at Test.Main () [0x00022] in /Users/chuck/Projects/Cobra/Workspace-Misc/Source/foo.cobra:line 5
+
+class Test
+
+    def main is shared
+        try
+            assert false
+        catch exc as Exception
+            assert 'debug.cobra:17' in exc.stackTrace or '520-debug.cobra:line 17' in exc.stackTrace

Tests/700-command-line/optFile/520-debugTest.cobra

@@ +1 @@
+class DebugTestDrvr
+
+    def main is shared
+        # needs to use args debug
+        sub = '520-debug.cobra'
+        optFile = '.cobrarc'
+        optFileLines = @[
+            '# optFile/520-debugTest',
+            'debug:true',
+            ]
+        File.writeAllLines(optFile, optFileLines)
+        
+        p as System.Diagnostics.Process?
+        CobraCore.runCobraExe(sub, out p)
+        assert p.exitCode == 0
+        File.delete(optFile)    

Tests/700-command-line/optFile/620-turboTest.cobra

@@ +1 @@
+class TurboDrvr
+
+    def main is shared
+        # needs to use args turbo:true
+        sub = '621-turbo.cobra'
+        optFile = '.cobrarc'
+        optFileLines = @[
+            '# optFile/620-turboTest',
+            'turbo:true',
+            ]
+        File.writeAllLines(optFile, optFileLines)
+        
+        p as System.Diagnostics.Process?
+        output = CobraCore.runCobraExe(sub, out p)
+        assert p.exitCode == 0
+        assert output.trim.length == 0
+        File.delete(optFile)    

Tests/700-command-line/optFile/621-turbo.cobra

@@ +1 @@
+# .skip. driven from 620-turboTest.cobra
+# needs args -turbo
+
+class Program
+
+    def main is shared
+        assert false
+        trace 
+        x = 1
+        trace all
+        trace x

Tests/700-command-line/optFile/700-run-args.cobra

@@ +1 @@
+# Test compile+run execution specifying args to run compiled prog with 
+
+class Test 
+
+    def main is shared 
+        cobraPath = CobraCore.findCobraExe to !
+        if 'Snapshot' in cobraPath
+            # TODO 2008-10-19: Not sure why this is happening yet.
+            print 'WARNING: Snapshot in cobra path:', cobraPath
+            cobraPath = cobraPath.replace('\\Snapshot\\', '\\')
+            cobraPath = cobraPath.replace('/Snapshot/', '/')
+
+        echo = '702-echo'
+        exp = 'argA argB argC'
+        .verify(cobraPath, '[echo]', exp, exp)
+
+        arg = '"1argA 2argB 3argC"'
+        exp =  '1argA 2argB 3argC :1' 
+        .verify(cobraPath, '[echo]', arg, exp)
+        
+        
+    def verify(cobraPath as String, prog as String, args as String, expectedText as String) is shared
+        p as System.Diagnostics.Process? 
+        optFile = '.cobrarc'
+        optFileLines = @[
+            '# optFile/700-run-args',
+            'run-args:[args]',
+            ]
+        File.writeAllLines(optFile, optFileLines)
+        
+        output = CobraCore.runCobraExe(cobraPath, prog, out p) 
+        File.delete(optFile)    
+        #print output 
+        assert 'Unhandled Exception' not in output 
+        assert expectedText in output 
+        assert p.exitCode == 0 

Tests/700-command-line/optFile/110-hello.cobra

@@ +1 @@
+class Hello
+    def main
+        print 'Hello'

Tests/700-command-line/optFile/610-include-tracesTest.cobra

@@ +1 @@
+class IncludeAssertsDrvr
+
+    def main is shared
+        # needs to use args include-traces:false
+        sub = '611-include-traces.cobra'
+        optFile = '.cobrarc'
+        optFileLines = @[
+            '# optFile/610-include-tracesTest',
+            'include-traces:false',
+            ]
+        File.writeAllLines(optFile, optFileLines)
+        
+        p as System.Diagnostics.Process?
+        output = CobraCore.runCobraExe(sub, out p)
+        assert p.exitCode == 0
+        assert output.trim.length == 0
+        File.delete(optFile)    

Tests/700-command-line/optFile/611-include-traces.cobra

@@ +1 @@
+# .skip. driven from 610-include-tracesTest.cobra
+# needs args  -include-traces:no
+
+class Program
+
+    def main is shared
+        tracer = CobraCore.tracer
+        tracer.destination = StringWriter()
+        x = 1
+        trace 
+        trace all
+        trace x
+        trace off
+        trace 'hello'
+        trace on
+        assert tracer.destination.toString == ''

Tests/700-command-line/optFile/600-include-assertsTest.cobra

@@ +1 @@
+class IncludeAssertsDrvr
+
+    def main is shared
+        # needs to use args include-asserts:false
+        sub = '601-include-asserts.cobra'
+        optFile = '.cobrarc'
+        optFileLines = @[
+            '# optFile/600-include-assertsTest',
+            'include-asserts:false',
+            ]
+        File.writeAllLines(optFile, optFileLines)
+        
+        p as System.Diagnostics.Process?
+        CobraCore.runCobraExe(sub, out p)
+        assert p.exitCode == 0
+        File.delete(optFile)    

Tests/700-command-line/optFile/601-include-asserts.cobra

@@ +1 @@
+# .skip. driven from 600-include-assertsTest.cobra 
+# needs to run with args -include-asserts:no
+
+class Program
+
+    def main is shared
+        assert false

Tests/700-command-line/optFile/400-foolib.cobra

@@ +1 @@
+# .args. -t:lib -embed-run-time:no
+
+class Foo
+
+    get one as int
+        return 1
+
+    get two as int
+        return 2
+
+    get name as String
+        return .getType.name
+
+    def computeString as String
+        return 'aoeuaoeu'
+
+    def checkInts(args as vari int) as int
+        for arg in args
+            assert arg
+        return args.length

Tests/700-command-line/optFile/116-highlight.cobra

@@ +1 @@
+# test -highlight option set in options file
+# . especially on a file with "def main" with no "is shared"
+
+class Test
+
+    def main
+        sourceFile = '110-hello.cobra'
+
+        source = File.readAllText(sourceFile)
+        assert 'is shared' not in source
+        
+        optFile = '.cobrarc'
+        hdr = '# optFile/116-highlight'
+        
+        File.writeAllLines(optFile, @[hdr,'highlight:true'])
+        
+        p as System.Diagnostics.Process?
+        output = CobraCore.runCobraExe('[sourceFile]', out p)
+        File.delete(optFile)    
+        assert p.exitCode == 0
+        # trace output  # on mac: output='Writing gen-html/110-hello.cobra.html\n\n\n
+        assert 'Writing ' in output and 'hello.cobra' in output
+        genFile = Path.combine('gen-html', '110-hello.cobra.html')
+        assert File.exists(genFile)
+        File.delete(genFile)

Tests/700-command-line/optFile/401-fooprogTest.cobra

@@ +1 @@
+# args to use are -embed-run-time:no -ref:400-foolib.dll
+class FooProgDriver
+
+    def main
+        sub = '402-fooprog.cobra'
+        optFile = '.cobrarc'
+        optFileLines = @[
+            '# optFile/401-fooprogTest',
+            'embed-run-time:no',
+            'ref:400-foolib.dll'
+            ]
+        File.writeAllLines(optFile, optFileLines)
+        
+        output = .runCobraExe('[sub]')
+        assert 'f.one is 1' in output
+        assert 'f.two is 2' in output
+        File.delete(optFile)    
+    
+    def runCobraExe(args as String) as String
+        p as System.Diagnostics.Process?
+        return CobraCore.runCobraExe(args, out p)

Tests/700-command-line/optFile/800-options-file.cobra

@@ +1 @@
+class OptionsFileDrvr
+
+    def main is shared
+        # needs to use args turbo:true
+        optFile = 'myOpt'
+        sub = '-options-file:[optFile] 621-turbo.cobra '
+        optFileLines = @[
+            '# optFile/800-options-file',
+            'turbo:true',
+            'out:turboWithopts',
+            ]
+        File.writeAllLines(optFile, optFileLines)
+        
+        p as System.Diagnostics.Process?
+        output = CobraCore.runCobraExe(sub, out p)
+        assert p.exitCode == 0
+        assert output.trim.length == 0
+        File.delete(optFile)    

Tests/700-command-line/optFile/402-fooprog.cobra

@@ +1 @@
+# .skip. driven from 401-fooprogTest
+# args are: embed-run-time:no    ref: 400-foolib.dll
+
+class Program
+
+    def main is shared
+        f = Foo()
+        print 'f.one is', f.one
+        print 'f.two is', f.two
+        name = f.name
+        .checkName(name)
+        s = f.computeString
+        .checkName(s)
+        assert f.checkInts(2, 4, 6) == 3
+
+    def checkName(name as String) is shared
+        assert name.length

Tests/700-command-line/optFile/510-lib-optionTest.cobra

@@ +1 @@
+class LibOptionDrvr
+
+    def main is shared
+        oldName = '400-foolib.dll'
+        newName = 'foolib.dll'
+        assert File.exists(oldName)
+
+        # put foolib.dll in a subdir        
+        libDir = Path.combine('..', 'libdir')
+        path = Path.combine(libDir, newName)
+        if File.exists(path)
+            File.delete(path)
+        File.copy(oldName, path)
+        
+        # needs to use args .compile-only, -lib:libdir -ref:foolib 
+        sub = '512-lib-option.cobra'
+        optFile = '.cobrarc'
+        optFileLines = @[
+            '# optFile/510-lib-optionTest',
+            'compile:true',
+            'lib:[libDir]',
+            'ref:foolib'
+            ]
+        File.writeAllLines(optFile, optFileLines)
+        
+        p as System.Diagnostics.Process?
+        CobraCore.runCobraExe(sub, out p)
+        assert p.exitCode == 0
+        File.delete(optFile)    
+    

Tests/700-command-line/optFile/118-time-it.cobra

@@ +1 @@
+class TimeIt
+
+    def main
+        sub = '110-hello.cobra'
+        optFile = '.cobrarc'
+        hdr = '# optFile/118-timeit'
+        
+        File.writeAllLines(optFile, @[hdr,'#empty options file'])
+        output = .runCobraExe('[sub]')
+        assert 'timeit =' not in output
+        assert 'Hello' in output
+            
+        File.writeAllLines(optFile, @[hdr, 'timeit:true'])
+        output = .runCobraExe('[sub]')
+        assert 'total' in output
+        assert 'execute =' in output
+        assert 'compile =' in output
+        assert 'lines compiled' in output
+        assert 'nodes compiled' in output
+        assert 'tokens compiled' in output
+        assert 'Hello' in output
+        File.delete(optFile)    
+        
+    def runCobraExe(args as String) as String
+        p as System.Diagnostics.Process?
+        return CobraCore.runCobraExe(args, out p)

Tests/700-command-line/optFile/801-options-fileName.cobra

@@ +1 @@
+# test options file with embedded filename to compile
+class OptionsFileDrvr
+
+    def main is shared
+        optFile = 'myOptwName'
+        sub = '-options-file:[optFile] '
+        optFileLines = @[
+            '# optFile/801-options-fileName',
+            'turbo:true',
+            'out:nameFmOpts',
+            '621-turbo.cobra',
+            ]
+        File.writeAllLines(optFile, optFileLines)
+        
+        p as System.Diagnostics.Process?
+        output = CobraCore.runCobraExe(sub, out p)
+        assert p.exitCode == 0
+        assert output.trim.length == 0
+        File.delete(optFile)    

Tests/700-command-line/optFile/512-lib-option.cobra

@@ +1 @@
+# .skip.  driven from 510-lib-optionTest.cobra
+# needs to use args -compile, -lib:libdir -ref:foolib 
+
+class Test
+
+    def main is shared
+        assert Foo().two == 2

Tests/700-command-line/optFile/702-echo.cobra

@@ +1 @@
+# .skip. Driven from 700-run-args
+class Echo
+    def main is shared
+        args = CobraCore.commandLineArgs
+        sep = ''
+        for a in args[1:]
+            print '[sep][a]' stop
+            sep = ' '
+        if args.count > 1
+            print ' :[args.count-1]' stop
+        print

Tests/700-command-line/optFile/650-out-option.cobra

@@ +1 @@
+# .skip. driven from 652-out-option-verify
+# needs args -compile  -out:outoption.exe
+
+class OutOption
+
+    def main is shared
+        print 'DateTime Now is', DateTime.now

Tests/700-command-line/optFile/652-out-option-verify.cobra

@@ +1 @@
+class OutOptionVerify
+
+    def main is shared
+        # needs to use args  -compile  -out:outoption.exe
+        sub = '650-out-option.cobra'
+        optFile = '.cobrarc'
+        optFileLines = @[
+            '# optFile/652-out-option-verify',
+            'compile:true',
+            'out:outoption.exe',
+            ]
+        File.writeAllLines(optFile, optFileLines)
+        
+        p as System.Diagnostics.Process?
+        output = CobraCore.runCobraExe(sub, out p)
+        assert p.exitCode == 0
+        assert 'Compilation succeeded' in output
+        File.delete(optFile)    
+        
+        
+        name = 'outoption.exe'
+        p1 = System.Diagnostics.Process()
+        p1.startInfo.fileName = name
+        output = CobraCore.runAndCaptureAllOutput(p1)
+        assert 'DateTime Now is' in output
+
+        
+ No newline at end of file

Developer/IntermediateReleaseNotes.text

@@ -58 +58 @@
 
     An above error about numeric types indicates that you may want to set the default numeric type with "@number [expectedType]" in a source file or "cobra -number:[expectedType]" at the command line.
 
+* Added support for a cwd default options file (.cobrarc, cobra.rc, cobra.init) to store multiple
+(optionally commented) cmdline options in. 
+Any options set on the commandline explicitly will override these. 
+Provide new commandline option     -options-file/-optfile/-of
+to allow to disable options file processing (-options-file:none) or to specify an alternative filename 
+to read from (-options-file:FILENAME).
 
+
 ================================================================================
 Library
 ================================================================================