Ticket #205: prop-from-var-fallback.patch

Source/CobraParser.cobra

@@ -1670 +1670 @@
         # TODO: if the var was declared separately, then warn about redeclaring its type, or error if the type is different
         possibleVarDef = .curBox.declForName(varName)
         if not possibleVarDef
-            if not initExpr and not declVarType
+            if initExpr or declVarType
+                varDef = BoxVar(token, token, .curBox, varName, declVarType, List<of String>(_isNamesStack), initExpr, nil, 'Automatic backing var for property "[name]".')
+                .curBox.addDecl(varDef)
+                return varDef
+            if not varName.startsWith('_') or varName.startsWith('__')
                 .throwError('There is no variable named "[varName]" to match the property "[name]".')
-            varDef = BoxVar(token, token, .curBox, varName, declVarType, List<of String>(_isNamesStack), initExpr, nil, 'Automatic backing var for property "[name]".')
-            .curBox.addDecl(varDef)
-            return varDef
+            # tried looking for '_varName' now try '__varName'
+            varName0, varName = varName, '_' + varName
+            possibleVarDef = .curBox.declForName(varName)
+            if not possibleVarDef
+                .throwError('There is no variable named "[varName0]" or "[varName]" to match the property "[name]".')
                 
         if possibleVarDef inherits BoxVar
             varDef = possibleVarDef

Tests/120-classes/500-properties/123-properties-from.cobra

@@ +1 @@
+# Test 'name from var' uses  '__name' if no '_name'
+class Point
+
+    # TODO: cover `pro` and `set`
+    # TODO: verify _x is protected and __y is private
+    
+    var _x as int       # protected
+    var __y as int      # private
+
+    var _xy = 200
+    var __xy = 220
+    
+    cue init
+        base.init
+        _x = 100
+        __y = 101
+
+    get x from var      # typical property with explicit _named var backing
+    
+    get y from var      # no _y var but there is __y
+    
+    pro xy from var     # map onto _xy
+
+    def moveBy(dx as int, dy as int)
+        _x += dx
+        __y += dy
+        
+    def main is shared  
+        p = Point()
+        assert p.x == 100
+        assert p.y == 101
+    
+        assert p.xy == 200
+        assert p._xy == p.xy
+        p.xy += 2
+        assert p.xy == 202
+        assert p._xy == p.xy
+        assert p.__xy == 220
+        assert p.xy <> p.__xy
+        
+        p.moveBy(2,2)
+        assert p.x == 102
+        assert p.y == 103
+        assert p._x == p.x
+        assert p.__y == p.y

Tests/120-classes/500-properties/123-properties-from-error.cobra

@@ +1 @@
+# Test 'name from var'  fails if no '_name' or '__name'
+class Point
+
+    var _x as int       # protected
+    var __y as int      # private
+
+    var _xy = 200
+    var __xy = 220
+    
+    cue init
+        base.init
+        _x = 100
+        __y = 101
+
+    pro xyz from var    
+                    # .error. no variable named "_xyz" or "__xyz" 

Developer/IntermediateReleaseNotes.text

@@ -467 +467 @@
 * Fixed: The expression `nil is x`, where `x` is a nilable type, generates a false error message.
 
 * Fixed: Only the last `test` of a series of tests is included in the compiler's output.
+
+* Made properties using 'from var' search for a __name if the _name search fails
+    before emitting an error. ticket:205