Ticket #211: implicit-line-cont-expr.patch

Source/Parser.cobra

@@ -108 +108 @@
         ensure .peek == token
         _tokens[_nextTokenIndex] = token
         
+    def drop(offset as int)
+        """
+        Remove the token offset fwd in the token stream
+        """
+        i = _nextTokenIndex + offset
+        if i < _tokens.count
+            #token = _tokens[i] to ?
+            #assert token.which == 'DEDENT'
+            _tokens.removeAt(i)
+
     def last as IToken?
         return .last(0)
 

Source/CobraParser.cobra

@@ -2787 +2787 @@
                         # support foo.bar where bar is a keyword. Ex: foo.this
                         right = MemberExpr(.grab) to Expr
                     else
-                        right = .expression(prec)
+                        right = _continuedExpression(prec, opToken to !)
                     if op == 'ASSIGN' and left inherits IdentifierExpr and (left to IdentifierExpr).name.startsWithNonLowerLetter
                         .recordError(ErrorMessages.localVariablesMustStartLowercase)
                     if op == 'DOT' and not right inherits IDotRightExpr
@@ -2798 +2798 @@
                 _leftStack.pop
         assert left
         return left to !
-
+        
     def expression2 as Expr
         if _spaceAgnosticExprLevel > 0, _spaceAgnostic
         peekToken = .peek
@@ -2923 +2923 @@
                         else
                             throw
 
+    var _implicitContinuationOps = [
+        'ASSIGN', 'AND', 'OR', 'STAR', 'SLASH', 'PLUS', 'MINUS',
+        'EQ', 'NE', 'LT', 'GT', 'LE', 'GE', 'IN', 'NOTIN',  
+        'PLUS_EQUALS', 'MINUS_EQUALS', 'STAR_EQUALS', 'SLASH_EQUALS', 'PERCENT_EQUALS', 
+        'SLASHSLASH', 'PERCENT', 'AMPERSAND', 'VERTICAL_BAR',   'CARET', 'DOUBLE_LT',   
+        'DOUBLE_GT', 'AMPERSAND_EQUALS', 'VERTICAL_BAR_EQUALS', 'CARET_EQUALS', 
+        'DOUBLE_LT_EQUALS', 'DOUBLE_GT_EQUALS', 'STARSTAR', 'STARSTAR_EQUALS' 
+    ]
+            
+    def _continuedExpression(prec as int, opToken as IToken) as Expr
+        """
+        Handle expression that may end in line with an implicit continuation character
+        """
+        choppedIndents =0
+        if .peek.which == 'EOL' and opToken.which in _implicitContinuationOps 
+            .grab   # eat the following EOL and remove any now hanging indents
+            while .peek.which == 'INDENT' 
+                .grab
+                choppedIndents += 1
+        right = .expression(prec)
+        if choppedIndents > 0 
+            # correct any following dedents for removed hanging indents
+            choppedIndents =_eatNextDedents(choppedIndents)
+        assert choppedIndents == 0
+        return right
+        
+    def _eatNextDedents(nDedents as int) as int
+        """
+        Look fwd to next DEDENT and consume the following nDedents.
+        Error if not enough dedents.
+        Provides resync for indentation swallowed after an implicit line continuation character 
+        """
+        nDedents0 = nDedents
+        ofset = 0
+        while .peek(ofset).which <> 'DEDENT'
+            ofset += 1 
+        while nDedents > 0 and .peek(ofset).which == 'DEDENT'
+            .drop(ofset)
+            nDedents -= 1
+        if nDedents <> 0 
+            .throwError('After implicit line continuation wrong indentation. Expecting [nDedents0] sequential dedents but got only [nDedents0 - nDedents]')
+        return nDedents
+        
     def multiTargetAssign(arg0 as Expr) as Stmt
         # id, |[id,]... = <expr>
         args = .commaSepExprsPartial('ASSIGN.EOL.', 'ASSIGN')

Tests/110-basics-two/150-line-continuation/120-implicit-line-cont-ops.cobra

@@ +1 @@
+# Test for implicit forms of line continuation: round brackets and trailing binary ops
+# ticket:211 (partially also addresses ticket 210)
+class Program
+
+    def main
+        assert 1 + 2 == 3       # ok
+            
+        assert (1 +     # braces ok
+            2) == 3
+        assert 1 *      # implicit trailing '*', 0 indent
+        2  == 2
+        
+        assert 1 +      # implicit trailing '+', 1 indent
+            2 == 3
+        #assert (1 +        # Ticket 210: Cannot mix tabs and spaces in indentation.
+        #      2)
+        #assert 1 +     # Both tickets.
+        #     2 == 3
+
+        assert (1 +     # braces, double indent
+                12) == 13
+        assert 1 +      # trailing '+', double indent after
+                2 == 3
+        assert 3 -      # trailing '-', double indent after
+                2 == 1
+                
+        assert 3 *      # ((3*1) + 4) -(8/2)  # multiple lines
+            1 +
+            4 -
+            8 /
+            2 == 3
+            
+        a = 1
+        b = 2
+        assert (a == 1 and  
+            b == 2)
+        assert a == 1 and   #implicit on 'and'
+            b == 2
+        assert a == 1 or    # implicit on or
+            b == 2
+
+        #assert a == 1 and  # implicit on and and tabs+spaces
+        #      b == 2
+
+