Ticket #27: 160-UseArrays.cobra

class ArraysExample
    """
    Shows how to declare and use array variables and literals
    """
    shared
     
        def sum(nums as int[]) as int
            test 
                # dynamic typing
                nums = @[1, 2, 3] # assign array literal; like list but  prefixed by @
                assert nums.length == 3
                assert nums[2] == 3 
                assert ArraysExample.sum(nums) == 6
                
                lottaNums = int[](10)  # dynamic typing explicitly sized array
                # contents inited to 'default value' 0
                # sized array initializer form is done by assignment to an arrayType constructor
                #   constructor arg is array size   var = Type[](size)
                # lottaNums as int[10] 
                # lottaNums as int[] = int[](10)    # explicitly typed 
                assert lottaNums.length == 10
                assert lottaNums[9] == 0
                assert ArraysExample.sum(lottaNums) == 0 
            body 
                sum = 0 
                for num in nums 
                    sum += num
                return sum 
            
        def main 
            parts = 'a|b:c'.split(@[c'|', c':']) # split() expects an array of chars
            assert parts.length == 3 
            for part in parts 
                print part 
                
            
class BinaryFileReader 
    is abstract
    """
    Abstract class that shows array handling for .Net binary file API
    Reads a file in 256 byte chunks. 
    Subclass and define handleBuf to provide content handling
    """
    shared
        var stdin = 'stdin'

    var _fileName as String

    def init(fileName as String)
        _fileName = fileName
        
    def readBinaryFile
        if _fileName == .stdin
            br = BinaryReader(Console.openStandardInput)
            ._readFile(br)
            return
            
        if not File.exists(_fileName)
            print "No File: [_fileName]"
            return
            
        #br = BinaryReader(File.open(_fileName, FileMode.Open))
        br = BinaryReader(FileStream(_fileName, FileMode.Open,FileAccess.Read))
        ._readFile(br)
    
    def _readFile(br as BinaryReader)
        buffer as Byte[] = Byte[](256) 
        #buffer as Byte[256]
        #buffer as Byte[] = sharp'new Byte[256]'

        fofset=0
        nRead = br.read(buffer, 0, 256)
        while nRead > 0     
            .handleBuf(buffer, nRead, fofset)
            fofset += nRead
            nRead = br.read(buffer, 0, 256)
        .fileEnd(fofset)    
        br.close
            
    
    def handleBuf( buffer as Byte[], nRead as int, fOffset as int)  is abstract
        """ 
        Called on each filled or partially filled buffer
        """

    def fileEnd(fOffset as int) is abstract
        """ 
        Called on eof before file closed
        """