Ticket #27: explicitArraySize.patch

Source/CobraParser.cobra

@@ -3008 +3008 @@
         # check for array
         bracket = .optional('LBRACKET')
         if bracket
+            sizeToken = nil
             if .peek.which=='INTEGER_LIT'
-                .throwError('Explicit array sizes are not currently supported.')
+                #.throwError('Explicit array sizes are not currently supported.')
+                #.throwError('Explicit array sizes are not specified this way for some obscure reason. Do as assignment to an arrayType with literal size in braces e.g. ia as int[] = int[](10)')
+                sizeToken = .grab
             .expect('RBRACKET')
-            t = ArrayTypeIdentifier(bracket, t)
-
+            if  sizeToken
+                size = sizeToken.value to int
+                t = SizedArrayTypeIdentifier(bracket, t, size)
+            else
+                t = ArrayTypeIdentifier(bracket, t)
+                
         # check for 'optional' aka 'can be nil'
         question = .optional('QUESTION')
         if question

Source/Types.cobra

@@ -1801 +1801 @@
 
     get name as String is override
         return _wrappedType.name+r'[]'
-
+        
+    get size as int
+        return -1
+    
     def isAssignableTo(type as IType) as bool is override
         if base.isAssignableTo(type)
             return true
@@ -1835 +1838 @@
     get sharpInit as String is override
         return 'null'
 
+class SizedArrayType
+    inherits ArrayType
+    
+    var _size as int
+    get size from var is override
+    
+    def init(wrappedType as IType, size as int)
+        base.init(wrappedType)
+        _size = size
 
+    get isReference as bool is override
+        return false
+
+    get sharpInit as String is override
+        return 'new [_wrappedType.sharpRef]' + r'[' + '[_size]' + r']'
+    
+        
 class VariType
     inherits ArrayType
     """
@@ -2002 +2021 @@
 
     def _resolveType as IType is override
         return ArrayType(_typeId.realType)
+        
+class SizedArrayTypeIdentifier
+    inherits ArrayTypeIdentifier
+    
+    var _size as int
+    
+    def init(token as IToken, typeId as AbstractTypeIdentifier, size as int)
+        base.init(token, typeId)
+        _size = size
+        
+    def _resolveType as IType is override
+        return SizedArrayType(_typeId.realType, _size)
+        
 
-
 class NilableTypeIdentifier
     inherits WrappedTypeIdentifier
 

Tests/110-basics-two/800-arrays/130-sized-single-dim-array.cobra

@@ +1 @@
+class ExplicitSizedArrayTest
+    """
+    Tests for new sized array type  - as Type[lit-size]
+    """
+    shared
+
+        def main
+            .sizedDcl
+            .slicedArr
+            
+        def sizedDcl
+            numbers as int[10]
+            assert numbers.length==10
+            for i as int in numbers
+                assert i==0
+
+            for i = 0 .. numbers.length
+                assert numbers[i]==0
+                numbers[i] = i
+                assert numbers[i]==i
+
+            names as String[] = @['aoeu']
+            assert names[0] == 'aoeu'
+            names[0] = 'Cobra'
+            assert names[0] == 'Co' + 'bra'
+
+            assert .names[0]=='aoeu'
+            assert .names[1]=='asdf'
+
+#TODO:          stuff as String?[1]
+
+            numbers = @[1, 2, 3]
+            assert numbers.length==3
+            assert numbers[0]==1
+
+            # test equality
+            num0 as int[] = int[](3)
+            num1 as int[3]
+            assert num0 == num1
+            
+            numbers0 = @[1, 2, 3]
+            numbers1 as int[3]
+            numbers1[0] = 1
+            numbers1[1] = 2
+            numbers1[2] = 3
+            assert numbers0 == numbers1
+            assert numbers1 == numbers1
+            
+        def names as String[2]
+            names as String[2]
+            names[0] = 'aoeu'
+            names[1] = 'asdf'
+            return names
+            
+        def slicedArr
+            numbers as int[3]
+            assert numbers[:-1] == @[0, 0]
+            assert numbers[1:] == @[0, 0]
+            assert numbers[:-2] == @[0]
+            numbers[0] = 1
+            numbers[1] = 2
+            numbers[2] = 3
+            assert numbers[:-1] == @[1, 2]
+            assert numbers[1:] == @[2, 3]
+            assert numbers[:-2] == @[1]
+                

Developer/IntermediateReleaseNotes.text

@@ -1 +1 @@
 Post 0.8
 
+* Add support for explicitly sized array as declaration type - ticket#27
+
 * Added a new built-in doc tool accessible via "cobra -doc ...". The documentation is generated to local HTML files using your declarations, doc strings, contracts, etc.
 
 * Add support for specifying unsigned integers as Hex literals