Ticket #273: tweaks.patch

Source/Cobra.Lang/Extensions.cobra

@@ -6 +6 @@
     extend System.Object
 
         def typeOf as System.Type
-            """ Using .typeOf is portable between platforms in contrast to CLR .getType and JVM .getClass. """
+            """
+            Return the Type of the object this is called on. 
+            Using .typeOf is portable between platforms in contrast to CLR .getType and JVM .getClass.
+            """
             return .getType
 
         def toTechString as String
+            """
+            Generate a 'technical' string representation of the object suitable for inspection and debugging.
+            Used for AssertExceptions (and subclasses such as RequireException) and the trace statement.
+            It provides more information about collections and enumerations and recovers from exceptions
+                when making strings so that debugging can proceed.
+            Intended to be similar to Python's repr() behavior.
+            """
             return CobraImp._techStringMaker.makeString(this)
 
         def toPrintString as String
+            """
+            Generate a string representation of the object suitable for printing.
+            Strings are only quoted if they are inside collections such as a list or dictionary.
+                This is similar to Python's str() behavior which has worked well in practice.
+            """     
             return CobraImp._printStringMaker.makeString(this)
 
 
@@ -38 +53 @@
                 return this[:1].toUpper + this[1:]
 
         def count(c as char) as int
+            """Return a count of the number of occurrences of the char in this string."""
             test
                 assert ''.count(c'x')==0
                 assert 'x'.count(c'x')==1
@@ -50 +66 @@
                 return count
 
         def isCapitalized as bool
+            """Return a bool indicating if this string is nonzero length and starts with an uppercase letter."""
             test
                 assert 'Aoeu'.isCapitalized
                 assert 'Zaoeu'.isCapitalized
@@ -60 +77 @@
                 return .length and this[0].isUpper
 
         def md5HashInHex as String
+            """Return a string of Hex characters of the md5 hash of this string."""
             ensure
                 result.length == 32
             test
@@ -81 +99 @@
             return .split(separator, count, StringSplitOptions.None)
 
         def split(separator as String, options as StringSplitOptions) as String[]
-            return .split(separator, 2_147_483_647, StringSplitOptions.None)  # CC: int.max
+            return .split(separator, 2_147_483_647, options)  # CC: int.max
 
         def split(separator as String, count as int, options as StringSplitOptions) as String[]
+            """
+            Return an array of strings being the split of this string on the separator string given,
+            up to a maximum of count items conforming to the given StringSplitOptions.
+            """
             require
                 count >= 0
             test
@@ -103 +125 @@
                 return .split(@[separator], count, options) to !
 
         def split(chars as List<of char>) as List<of String>
+            """Split this string on any of the list of chars given returning a List of Strings."""
             test
                 s = 'a,b:c:d,e,f'
                 assert s.split([c',', c':']) == ['a', 'b', 'c', 'd', 'e', 'f']
@@ -110 +133 @@
                 return List<of String>(.split(chars.toArray) to !)
     
         def split(chars as IList<of char>) as List<of String>
+            """Split this string on any of the IList of chars given returning a List of Strings."""
             charsArray = char[](chars.count)
             for i in chars.count, charsArray[i] = chars[i]
             return List<of String>(.split(charsArray))
@@ -120 +144 @@
         def splitLines(keepEnds as bool) as List<of String>
             """
             Returns the string split into lines, recognizing the various line endings (posix, dos/http, old mac) even if mixed within the same string.
+            If keepEnds is true the nl separators are left on the end of each line.
             """
             test
                 cases = [
@@ -189 +214 @@
                 return lines
 
         def splitWords as List<of String>
+            """Split this string int (non whitespace) words returning them as a list of strings."""
             test
                 # preliminary:
                 assert 'foo bar'.split == ['foo', 'bar']

Source/Cobra.Lang/ExtendIEnumerable.cobra

@@ -49 +49 @@
     extend IEnumerable<of T>
 
         def toList as List<of T>
+            """Turn an IEnumerable of T into a list of T."""
             return List<of T>(this)
 /#
     TODO: cannot do the following yet due to a bug in extensions and how they are chosen with respect to inheritance

Source/Cobra.Lang/ExtendList.cobra

@@ -59 +59 @@
                 return newList
 
         def get(flexibleIndex as int) as T
+            """
+            Return item at flexibleIndex. if flexibleIndex <0 return item at flexibleIndex+count.
+            i.e offset from end of list 
+            so .get(0) returns first item in list, .get(-1) returns last item,
+              .get(-2) returns second to last item, ...., get(-.count) returns first item.
+            Index values outside list index range cause RequireException.
+            """
             require
                 .count > 0
                 (flexibleIndex >= 0 and flexibleIndex < .count) _
@@ -68 +75 @@
                 return this[flexibleIndex]
         
         def get(flexibleIndex as int, default as T) as T
+            """
+            Return item at flexibleIndex. if flexibleIndex <0 return item at flexibleIndex + this.count.
+            Index values outside list index range return default.
+            """ 
             ensure
                 .count == 0 implies result == default
                 (flexibleIndex > .count or flexibleIndex < -.count) _
@@ -114 +125 @@
                 yield KeyValuePair<of int, T>(index, this[index])
 
         def random as T
+            """Return an item at a random postion in the list"""
             require .count > 0
             return .random(CobraCore.random)
 
@@ -122 +134 @@
             return this[r.next % .count]
 
         def removeLast
+            """Remove the last item in the list."""
             require .count > 0
             ensure .count == old .count - 1
             .removeAt(.count-1)
         
+        def push(value as T)    
+            """ Push value onto front/top of List. """
+            .add(value)
+
+        def pop as T    
+            """ Pop value off front/top of List. """
+            require .count > 0
+            value = this[.count-1]
+            .removeLast
+            return value
+            
         def reversed as List<of T>
+            """ Return a copy of this list reversed."""     
             ensure
                 result is not this
                 result.count == .count
@@ -136 +161 @@
                 return t
     
         def sorted as List<of T>
+            """ Return a copy of this list sorted."""       
             ensure
                 result is not this
                 result.count == .count
@@ -252 +278 @@
             else
                 expect ArgumentOutOfRangeException, t.last
     
+            # push/pop
+            t = [0]
+            t.pop
+            t.push(10)
+            assert t.count ==1 and t[0] == 10
+            t.push(11)
+            assert t.count == 2 
+            assert t[0] == 10 and t[1] == 11
+            t.push(12)
+            assert t.count == 3 
+            assert t[0] == 10 and t[1] == 11 and t[2] == 12
+            assert t.pop == 12
+            assert t.count == 2  and t[1] == 11 and t[0] == 10
+            t.push(21)
+            assert t.count == 3  and t[2] == 21 and t[1] == 11 and t[0] == 10
+            assert t.pop == 21
+            assert t.pop == 11
+            assert t.count ==1 and t[0] == 10
+            assert t.pop == 10 and t.count ==0
+            if hasContracts
+                expect RequireException, t.pop
+            else
+                expect ArgumentOutOfRangeException, t.pop
+            
             # numbered
             t = [10, 20, 30]
             count = 0

Source/Node.cobra

@@ -4 +4 @@
 class SubnodesAttribute inherits Attribute
     """
     Put this attribute on properties that represent a collection of subnodes of the declaring node class.
-    Node.reploceChild will use these properties when searching for node references to be replaced (which happens during node transformation).
+    Node.replaceChild will use these properties when searching for node references to be replaced (which happens during node transformation).
     There may be other uses for this in the future.
     The property value should respond to .indexOf(node) and "subnodes[index] = newNode" which are covered by List<of>.
     Since dynamic binding is used, inheriting from List<of> is not strictly required.

Source/CobraParser.cobra

@@ -1 +1 @@
 """
 The Cobra Parser
+    Recursive descent parser for the Cobra Language. 
+    Uses CobraTokeniser to obtain a stream of Cobra Lexical tokens,
+    then walks through these Tokens generating Nodes (subclasses of) for recognised constructs which get 
+        assembled into a Tree of (Syntax)Nodes rooted on a Cobra Module (Node).
 
 Rules:
     * Do not invoke Box.memberForName. Use Box.declForName instead. Inheritance relationships are not established during parsing.
@@ -90 +94 @@
     var _uppercaseLetters = 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'
 
     var _isNamesStack as Stack<of String>?
+        """Stack for recording modifier for items in modifier sections (e.g.shared)"""
+
     var _boxStack as Stack<of Box>?
+        """Stack to record the box the current level of box member decls is for."""
 
     var _globalNS as NameSpace?
     var _nameSpaceStack as Stack<of NameSpace>
@@ -179 +186 @@
 
     def parseSource(fileName as String, source as String) as CobraModule
         """
-        Parses module source code and returns resulting module.
+        Parses module source code and returns resulting (cobra) module.
         The fileName is recorded, but the file is not physically accessed.
         After parsing, .references will hold a list of any @ref directive references that were parsed.
         """
@@ -199 +206 @@
 
     def _preParseSource(fileName as String, source as String) as bool
         """
-        Sets up for parsing, but does not invoke `parseTokens`.
+        Sets up for parsing - inits stack variables, generates token stream and handles explicit line continuation, 
+            but does not invoke `parseTokens`.
         Used by `parseSource` and various test sections.
         Returns true if successful, false if there were one or more errors.
-        Upon success, you can use token methods lik .grab.
+        Upon success, you can use token methods like .grab.
         Does not .throwError but may .recordError.
         """
         _fileName = fileName
@@ -337 +345 @@
 
     def _parseTokens as CobraModule
         """
-        Parses and then returns an instance of Module.
+        Parses and then returns an instance of (Cobra)Module.
         """
         .zeroOrMore('EOL')
         docString = .docString
@@ -524 +532 @@
     var _syntaxForClassInheritanceMsg = 'The syntax for inheritance is to put "inherits BaseClass" on the following line, indented.'
 
     def assemblyDecl as AssemblyDecl
+        """
+        Parse attribute entries for an assembly attributes declaration
+        """
         token = .expect('ID')
         assert token.text == 'assembly'
         .indent
@@ -674 +685 @@
                 .throwError('Cannot nest a type underneath a [parentBox.englishName]')  # TODO: needs a test case
 
         _boxStack.push(theClass)
-#       .isNamesStack = Stack<of String>
         .bodiedBoxMemberDecls(theClass)
         _boxStack.pop
 
@@ -751 +761 @@
         """
         hasIsNames = false
         names = _isDeclNamesNoEOL(out hasIsNames)
-        if hasIsNames
+        if hasIsNames 
             .endOfTypeSpecClause
-        # TODO: error on virtual and override
-        # TODO: error on virtual and shared
-        # TODO: error if 2 or more of 'public', 'protected', 'private', 'internal'
         return names
 
     def _isDeclNamesNoEOL(hasIsNames as out bool) as List<of String>
@@ -781 +788 @@
                 if .peek.text in .validIsNames
                     .throwError(.peek, 'Multiple access modifiers should be separated by commas such as "[what], [.peek.text]".')
                 break
-        # TODO: error on virtual and override
         # TODO: error on virtual and shared
-        # TODO: error if 2 or more of 'public', 'protected', 'private', 'internal'
+        # error on non virtual and override
+        if 'nonvirtual' in names and 'override' in names
+            .recordError(.last, 'Cannot specify both "nonvirtual" and "override".')
+        # error if 2 or more of 'public', 'protected', 'private', 'internal'
+        protModCount=0
+        for p in _validProtModifiers
+            if p in names, protModCount += 1
+        if protModCount > 1
+            .recordError(.last, 'Can only specify one of "public", "protected", "private" or "internal".')
         return names
 
     var _validIsNames as List<of String>?
+    var _validProtModifiers = ['public', 'protected', 'private', 'internal']
 
     get validIsNames as List<of String>
         if _validIsNames is nil
@@ -867 +882 @@
 
         # TODO when supporting nested classes, look at the _boxStack and set a back pointer here
         _boxStack.push(theMixin)
-#       .isNamesStack = Stack<of String>
         .bodiedBoxMemberDecls(theMixin)
         _boxStack.pop
 
@@ -906 +920 @@
         theInterface = Interface(wordToken, idToken, name, .makeList<of IType>(genericParams), typeSpecs.isNames, typeSpecs.attributes, typeSpecs.inheritsProxies, docString)
 
         _boxStack.push(theInterface)
-#       .isNamesStack = Stack(str)
         .bodiedBoxMemberDecls(theInterface)  # TODO: this shouldn't be bodiedBoxMemberDecls, right?
         _boxStack.pop
 
@@ -944 +957 @@
                 .throwError('Cannot nest a type underneath a [parentBox.englishName]')  # TODO: needs a test case
 
         _boxStack.push(theStruct)
-#       .isNamesStack = Stack(str)
         .bodiedBoxMemberDecls(theStruct)
         _boxStack.pop
 
@@ -1536 +1548 @@
         
     def declareProperty as ProperDexer?
         """
+        Parse full ('pro') form of a property (and indexer)
         Example source
             pro age as int
                 get
@@ -1639 +1652 @@
             return prop
 
     def declarePropertyFrom(token as IToken, idToken as IToken, name as String, coverWhat as String) as Property
+        """Parse the 'from ...' form of pro/get/set property decl."""
         require coverWhat.isOneOf('get.set.getset.')
         if .optional('VAR')
             varName = '_' + name
@@ -1687 +1701 @@
             varDef = possibleVarDef
         else
             .throwError('A property can only cover for variables. [varName] is a [possibleVarDef].')  # TODO: .englishName?
+        # 'from varName' can only be on _ prefixed varnames otherwise cant resolve/rename the varName correctly
+        if not varName.startsWith('_')
+            sugg = 'You need "_[varName]" instead of "[varName]" or instead must use the full "pro...get...set" property declaration form.'
+            .throwError('Explicitly specified property backing variable names must begin with an underscore prefix in the "from" form of a property. [sugg]')
         if initExpr and not varDef.setInitExpr(initExpr to !)   
             .throwError('Property backing variable "[varName]" has already been initialized.') # include line# of backing variable decl
         return varDef
@@ -1699 +1717 @@
 
     def _declareGetOrSetOnlyProperty(getOrSet as int) as ProperDexer?
         """
+        Parse shortcut forms (get and set) of property (and indexer) declarations.
+        
         Example source
             get meaningOfLife as int
                 return 42

Tests/720-libraries/900-cobra-std-lib/300-list-as-stack.cobra

@@ +1 @@
+# test use of list as stack - push/pop RTL ExtendList.cobra
+class ListAsStack
+    def main is shared      
+        t = [0] # [] as List<of int> 
+        assert t.pop == 0
+        t.push(10)
+        assert t.count ==1 and t[0] == 10
+        t.push(11)
+        assert t.count == 2 
+        assert t[0] == 10 and t[1] == 11
+        t.push(12)
+        assert t.count == 3 
+        assert t[0] == 10 and t[1] == 11 and t[2] == 12
+        assert t.pop == 12
+        assert t.count == 2  and t[1] == 11 and t[0] == 10
+        t.push(21)
+        assert t.count == 3  and t[2] == 21 and t[1] == 11 and t[0] == 10
+        assert t.pop == 21
+        assert t.pop == 11
+        assert t.count ==1 and t[0] == 10
+        assert t.pop == 10 and t.count ==0
+        expect RequireException 
+            t.pop
+        
+        s = List<of String>()
+        s.push('hello')
+        s.push('mike')
+        assert s.count == 2 and s.last == 'mike'
+        s.push('.')
+        assert s.count ==3 and s.last == '.'
+        assert s.pop == '.'
+        assert s.count ==2 and s.last == 'mike'
+        s.push(',')
+        assert s.count ==3 and s.last == ','
+        assert s.pop == ','
+        assert s.count ==2 and s.last == 'mike'
+        assert s.pop == 'mike'
+        assert s.count == 1 and s[0] == 'hello'
+        s.clear
+
+        s = [ 'hi', 'haere mai', 'gidday']
+        s.push('konnichiwa')
+        s.add('aloha')
+        c = s.count
+        s.pop
+        assert s.count == c-1
+        assert s.pop == 'konnichiwa'
+        assert s.pop == 'gidday'
+        assert s.pop == 'haere mai'
+        assert s.count == 1 and s.last == 'hi'
+        assert s.pop == 'hi'
+        expect RequireException 
+            s.pop
+        
+        

Tests/820-errors/400-declarations/420-accessor-err.cobra

@@ +1 @@
+# accessor error: both nonvirtual and override
+class AccessorTestB
+    def xx 
+        print 'in AccessorTestB.xx'
+    
+class AccessorTest inherits AccessorTestB
+    def xx is nonvirtual, override #.error. cannot specify both
+        print 'in xx'
+        
+    def main is shared
+        x = AccessorTest()
+        x.xx

Tests/820-errors/400-declarations/410-prop-pro-from-err.cobra

@@ +1 @@
+class MClass
+    var mlog = ''
+    
+    cue init
+        base.init
+        .addLog('initializer called.')  
+        
+    def xx as String
+        v ='foo magoo.'
+        .addLog(v) 
+        return v
+
+    def addLog(s as String)
+        .mlog += s 
+        .mlog += '\n'
+        
+    pro getLog from mlog 
+    # .error. names must begin with an underscore prefix    
+class EPoint
+    def main is shared
+        x = MClass()
+        print x.xx
+        print '- LOG -'
+        print x.getLog.trimEnd

Tests/820-errors/400-declarations/422-prot-mod.cobra

@@ +1 @@
+class AccessorTest
+    def xx is private, protected #.error. can only specify one
+        pass
+    
+    def xx1 is public, internal, protected  #.error. can only specify one
+        pass
+        
+    def xx is public, private  #.error. can only specify one
+        pass
+        
+    def xx is internal, private  #.error. can only specify one
+        pass
+        
+    def xx is internal, public, private, protected   #.error. can only specify one
+        pass
+        
+    def main is shared
+        x = AccessorTest()
+        x.xx

Tests/820-errors/400-declarations/412-prop-get-from-err.cobra

@@ +1 @@
+class MClass
+    var mlog = ''
+    
+    cue init
+        base.init
+        .addLog('initializer called.')  
+        
+    def xx as String
+        v ='foo magoo.'
+        .addLog(v) 
+        return v
+
+    def addLog(s as String)
+        .mlog += s 
+        .mlog += '\n'
+        
+    #pro getLog as String
+    #   get
+    #       #print .mlog
+    #       return .mlog
+
+    get getLog from mlog 
+    # .error. names must begin with an underscore prefix        
+class EPoint
+    def main is shared
+        x = MClass()
+        print x.xx
+        print '- LOG -'
+        print x.getLog.trimEnd