Ticket #339: nil-safe-deref.patch

Source/Expr.cobra

@@ -1304 +1304 @@
     def setDefinition(value as INamedNode?)
         # cannot override definition with a set, because base does not do a set
         _definition = value
+        # override use detection for compiler generated variables - not being set under normal checks
+        if .isCompilerMade, _definition.isUsed = true
+            
 
     get canBeStatement as bool is override
         return _definition inherits Method
@@ -1337 +1340 @@
         else
             return nil
 
+    pro isCompilerMade from var as bool
+        """ flag as internally created."""      
+        
     def _bindImp is override
         base._bindImp
         if _definition is nil
@@ -1732 +1738 @@
     def _bindImp is override
         base._bindImp
         assert .superNode inherits DotExpr
-        assert .binarySuperNode.op == 'DOT'
+        assert .binarySuperNode.op == 'DOT' or .binarySuperNode.op == 'QUESTION_DOT'
         assert .binarySuperNode.right is this
         left = .binarySuperNode.left
         if _definition is nil or _type is nil

Source/BinaryOpExpr.cobra

@@ -50 +50 @@
                     return AssignExpr(opToken, op, left, right)
                 on 'DOT'
                     return DotExpr(opToken, op, left, right)
+                on 'QUESTION_DOT'
+                    # convert nilSafe to cascaded non-nil coalesce
+                    #nilSafeHelper variable : (tv0 = left) ! (tv1 = tv0.right)
+                    bangToken = opToken.copy('BANG', '!')
+                    serNo = IdentifierExpr(opToken).serialNum                   
+                    tmpNameToken = opToken.copy('ID', 'tnsh_[serNo]' )  # tnsh = tmp nilsafe helper
+                    leftId = IdentifierExpr(tmpNameToken)               # new id to capture value of this expr tv0
+                    leftId.isCompilerMade = true
+                    assToken = opToken.copy('ASSIGN', '=')
+                    if left inherits InverseCoalesceExpr                # previous InverseCoalesce
+                        prevId = (left.right to AssignExpr).left          # tv1
+                        dotex = DotExpr(opToken, 'DOT', prevId, right)    # tv1.right
+                        rhs = AssignExpr(assToken, 'ASSIGN', leftId, dotex)   # tv2 = tv1.right
+                        ice = InverseCoalesceExpr(bangToken, 'BANG', left, rhs) # (<prev-ice) ! (tv2 = tv1.right)
+                    else
+                        assign = AssignExpr(assToken, 'ASSIGN', leftId, left) #tv0 = left
+                        lhs = assign
+                        serNo = IdentifierExpr(opToken).serialNum             # for a different serNo
+                        rightId = IdentifierExpr(opToken.copy('ID', 'tnsh_[serNo]')) # tv1 = tv0.right
+                        rightId.isCompilerMade = true
+                        rhs = AssignExpr(assToken, 'ASSIGN', rightId, DotExpr(opToken, 'DOT', leftId, right))
+                        ice = InverseCoalesceExpr(bangToken, 'BANG', lhs, rhs)
+                    return ice
                 on 'INHERITS' or 'IMPLEMENTS'
                     return InheritsExpr(opToken, op, left, right)
                 on 'IN' or 'NOTIN'
@@ -633 +656 @@
 
     cue init(opToken as IToken, op as String, left as Expr, right as Expr)
         require
-            op == 'DOT'
+            op == 'DOT' or op == 'QUESTION_DOT'
             right inherits IDotRightExpr 
         body
             base.init(opToken, op, left, right)
@@ -1043 +1066 @@
     cue init(opToken as IToken, op as String, left as Expr, right as Expr)
         base.init(opToken, op, left, right)
 
+    def addMinFields
+        base.addMinFields
+        .addField('left.toCobraSource', .left.toCobraSource)
+        .addField('right.toCobraSource', .right.toCobraSource)
+
     def _bindImp
         base._bindImp
         left, right = .left, .right

Source/CobraParser.cobra

@@ -2731 +2731 @@
             'LBRACKET':         80,
             'LPAREN':           80,
             'ARRAY_OPEN':       80,
+            'QUESTION_DOT':     80,
 
             'STARSTAR':         70,  # right associative
 
@@ -2910 +2911 @@
                         # support to expression. Ex: x to int  Ex: x to? Shape
                         right = .typeExpr to Expr
                         getTypeExprForRightHandSide = false
-                    else if op == 'DOT' and .peek.isKeyword
+                    else if (op == 'DOT' or op == 'QUESTION_DOT') and .peek.isKeyword
                         # support foo.bar where bar is a keyword. Ex: foo.this
                         right = MemberExpr(.grab) to Expr
-                    else if op == 'DOT' and _isHelpDirective(.peek)
+                    else if (op == 'DOT' or op == 'QUESTION_DOT') and _isHelpDirective(.peek)
                         # support foo.@help
                         left.isHelpRequested = true
                         op = ''  # cancel the creation of a new binary op expr
                         .grab
                     else
                         right = _continuedExpression(prec, opToken)
-                    if op == 'DOT' and not right inherits IDotRightExpr
+                    if (op == 'DOT' or op == 'QUESTION_DOT') and not right inherits IDotRightExpr
                         if left inherits StringLit or right inherits StringLit
                             sugg = ' Use plus "+", not dot ".", for string concatenation.'
                         else
@@ -3310 +3311 @@
         """
         nameToken = .idOrKeyword
         name = nameToken.text
-        if .opStack.count and .opStack.peek=='DOT'
+        if .opStack.count and (.opStack.peek=='DOT' or .opStack.peek=='QUESTION_DOT')
             return MemberExpr(nameToken)
         if .peek.which=='AS'
             return AsExpr(.grab, nameToken, .typeId)

Source/CobraTokenizer.cobra

@@ -239 +239 @@
             r'DOUBLE_LT_EQUALS      s   <<=',
             r'DOUBLE_GT_EQUALS      s   >>=',
 
+            r'QUESTION_DOT      s   ?.',
             r'QUESTION_EQUALS   s   ?=',
             r'BANG_EQUALS       s   !=',
         ]

Tests/900-compiler-lib/300-keywords.cobra

@@ -1 +1 @@
 # this used to fail due to a bug in the KeywordSpecs class
-
+@ref 'Test.Cobra.Compiler'
 use Cobra.Compiler
 
 class KeywordDescriptions

Tests/320-misc-two/410-nil-safe/020-nil-safe.cobra

@@ +1 @@
+class NilSafe
+    var co as Company?
+    var co1 as Company?
+    var ccnil as Object?
+    
+    def main is shared
+        ns = NilSafe()
+        co = Company()
+        co.name ='H Die and Tool'
+        ns.co = co
+    
+        assert ns.co.name == co.name
+        name = ns.co ! ns.co.name ? 'x'
+        assert name == co.name 
+
+        name = ns.co1?.name ? 'no-Name?'
+        # name = (t=ns.co1) : t.name )
+        assert name == 'no-Name?'
+    
+        #name = (t=ns.co) ! t.name ? 'x'
+        #assert name == co.name 
+        
+        ns1 as NilSafe?
+        name =  ((t0=ns1) ! (t1=t0.co1)) ! t1.name ? 'no.Name?'
+        assert name == 'no.Name?'
+        name =  ns1?.co1?.name ? 'no.Name?'
+        assert name == 'no.Name?'
+        
+    def x
+        pass
+    
+    invariant .ccnil == nil
+    
+class Company
+    var name as String?
+    
+    

Tests/320-misc-two/410-nil-safe/040-nil-safe-non-idempotent.cobra

@@ +1 @@
+# non idempotent: calls changing return values on each call
+class NilSafe
+    var co as Company?
+    var co1 as Company?
+    
+    def main is shared
+        ns = NilSafe()
+        co = Company()
+        co.name ='Hops Die and Tool'
+        ns.co = co
+    
+    
+        #print ns.co.chkCo ? 'chkFail'
+        #print ns.co.chkCo ? 'chkFail'
+        ns2 = ns to ?
+        r = ns2 ! ns2.co ! ns2.co.chkCo ? 'chkFail'
+        assert r == 'OK'
+        r = ns2 ! ns2.co ! ns2.co.chkCo ? 'chkFail'
+        assert r == 'chkFail'
+    
+        ns2 =NilSafe()
+        n = ns2.coCalc.name 
+        assert n == 'Synth1'
+        n = ns2.coCalc.name 
+        assert n == 'Synth2'
+        # ns2?.coCalc?.name
+        #n1 = ns2 ! ns2.coCalc ! ns2.coCalc.name
+        n1 = (t=ns2) ! (t1=t.coCalc) ! t1.name
+        assert n1 == 'Synth3'
+        ## ns2.coCalc?.name
+        n1 = ns2 ! (u=ns2.coCalc) ! u.name
+        assert n1 == 'Synth4'
+    
+        n1 = ns2?.coCalc?.name
+        assert n1 == 'Synth5'
+        #print n1 
+        n1 = ns2.coCalc?.name
+        assert n1 == 'Synth6'
+        #print n1
+        
+    def coCalc as Company?
+        return .co1 ? Company(dname='Synth[Company.cnt]')
+
+class Company
+    shared
+        var cnt = 0
+    var name as String? =''
+    var n =0
+
+    set dname from name
+
+    cue init
+        base .init
+        Company.cnt += 1
+        
+    def chkCo as String?
+        n = .n
+        .n += 1
+        if n ==0, return 'OK'
+        return nil
+    
+    def chkN as int
+        n, .n = .n, .n+1
+        return n

Tests/320-misc-two/410-nil-safe/030-many-nil-safe.cobra

@@ +1 @@
+class NilSafe
+    var co as Company?
+    var co1 as Company?
+    
+    def main is shared
+        ns = NilSafe()
+        co = Company()
+        co.name ='Die and Tool'
+        co.subsid = Company()
+        co.subsid.name = 'Just Tool'
+        ns.co = co
+        
+        assert ns.co.name == co.name
+        name = ns.co1?.name ? 'X?'
+        assert name == 'X?'
+        
+        n2=  ns.co1 ! ns.co1.name ? 'X!'
+        assert n2 == 'X!'
+    
+        ns1 as NilSafe?
+        name =  ns1?.co1?.name ? 'X?'
+        assert name == 'X?'
+        name = ns.co?.name ? 'X'
+        assert name == co.name
+        
+        ssname = ns.co?.subsid?.name ? 'X'
+        assert ssname == 'Just Tool'
+        ns.co?.subsid.subsid =Company()
+        ns.co.subsid.subsid.name= 'Justy'
+        ns1 = ns
+        name = ns1?.co?.subsid?.subsid?.name ? 'X'
+        assert name == 'Justy'
+        
+        ns1.co.subsid.subsid.name = nil
+        name = ns1?.co?.subsid?.subsid?.name ? 'X'
+        assert name == 'X'
+        ns1.co.subsid.subsid = nil
+        name = ns1?.co?.subsid?.subsid?.name ? 'X'
+        assert name == 'X'
+    
+        coX = ns.co?.subsid?.subsid ? co
+        assert coX.name == 'Die and Tool'
+    
+        coX1 = ns1?.co?.subsid?.subsid ? co
+        assert (coX1 to Company).name == 'Die and Tool'
+        
+class Company
+    var name as String?
+    var subsid as Company?
+    

Tests/320-misc-two/410-nil-safe/010-simple-nil-safe.cobra

@@ +1 @@
+class NilSafe
+    var co as Company?
+    var co1 as Company?
+    var ccnil as Object?
+    
+    def main is shared
+        ns = NilSafe()
+        co = Company()
+        co.name ='H Die and Tool'
+        ns.co = co
+    
+        assert ns.co.name == co.name
+        name = ns.co ! ns.co.name ? 'x'
+        assert name == co.name 
+
+        name = ns.co1?.name ? 'no-Name?'
+        assert name == 'no-Name?'
+        
+        n2=  ns.co1 ! ns.co1.name ? 'noName!'
+        assert n2 == 'noName!'
+    
+        ns1 as NilSafe?
+        name =  ns1?.co1?.name ? 'no.Name?'
+        assert name == 'no.Name?'
+        
+        n2 = ns1 ! ns1.co1 ! ns.co1.name ? 'no.Name!'
+        assert n2 == 'no.Name!'
+    
+        ns1 = NilSafe()
+        name =  ns1?.co1?.name ? 'no.Name-co?'
+        assert name == 'no.Name-co?'
+    
+        n2 = ns1 ! ns1.co1 ! ns1.co1.name ? 'no.Name-co!'
+        assert n2 == 'no.Name-co!'
+    
+        ns1.co1 = Company()
+        name =  ns1?.co1?.name ? 'no.Name-co-name?'
+        assert name == 'no.Name-co-name?'
+    
+        n2 = ns1 ! ns1.co1 ! ns1.co1.name ? 'no.Name-co-name!'
+        assert n2 == 'no.Name-co-name!'
+    
+        ns1.co1.name = 'xx'
+        name =  ns1?.co1?.name ? 'no.Name-co-name?'
+        assert name == 'xx'
+    
+    def x
+        pass
+    
+    invariant .ccnil == nil
+    
+class Company
+    var name as String?
+    
+