Ticket #71: for-expr-numeric.patch

Source/Expr.cobra

@@ -865 +865 @@
     var _what as Expr
     var _whereExpr as Expr?
     var _getExpr as Expr
+    var _start as Expr?
+    var _stop as Expr?
+    var _step as Expr?
 
-    def init(token as IToken, nameExpr as NameExpr, what as Expr, whereExpr as Expr?, getExpr as Expr)
+    def init(token as IToken, nameExpr as NameExpr, what as Expr, stopExpr as Expr?, 
+                stepExpr as Expr?, whereExpr as Expr?, getExpr as Expr)
         base.init(token)
         _nameExpr = nameExpr
         _what = what
+        _stop = stopExpr
+        _step = stepExpr
         _whereExpr = whereExpr
         _getExpr = getExpr
 
@@ -880 +886 @@
         .addField('what', _what)
         .addField('whereExpr', _whereExpr)
         .addField('getExpr', _getExpr)
+        .addField('start', _start)
+        .addField('stop', _stop)
+        .addField('step', _step)
 
     get willChangeVar as bool is override
         # TODO: ack. kind of weird. if the variable is a new one and its not read afterwards (without first being set) then no side effects.
@@ -892 +901 @@
         base._bindImp
         _what.bindImp  # bind first because it may be needed for type inference
         whatType = _what.type to !
-        if not whatType.isDescendantOf(.compiler.enumerableType) and not whatType.isSequenceLike  # TODO: can probably drop .isSequenceLike
+        if whatType inherits AnyIntType
+            if _stop
+                _start = _what
+                _stop.bindImp
+            else
+                _start = IntegerLit(.token.copy('INTEGER_LIT', '0'), 0).bindImp
+                _stop = _what
+            if not _step
+                _step = IntegerLit(.token.copy('INTEGER_LIT', '1'), 1)
+            _step.bindImp
+        else if not whatType.isDescendantOf(.compiler.enumerableType) and not whatType.isSequenceLike  # TODO: can probably drop .isSequenceLike
             .throwError('Cannot enumerate values of type "[whatType.name]". You can enumerate anything enumerable (IEnumerable, IList, arrays, strings, etc.).')
         _var = .bindVar(_nameExpr)
         if _nameExpr.definition
@@ -913 +932 @@
 
     def inferredType as IType? is override
         assert _what.type
-        return _what.type.innerType
+        return if(_what.type inherits AnyIntType, _what.type, _what.type.innerType)
 
 
 class IdentifierExpr

Source/Cobra.Lang/Native.cs

@@ -774 +774 @@
         return results;
     }
 
+    /* Numeric forExpr */
+    static public List<int> For<TIn, TOut>(int start, int stop, int step, ForGet<int, int> forGet) {
+        if ((step > 0 && start > stop) || 
+            (step < 0 && start < stop) || step == 0)
+                    throw new IndexOutOfRangeException(string.Format("ForExpr will never terminate; start={0} stop={1} step={2}",start, stop,step));
+        List<int> results = new List<int>();
+        for ( int item = start; 
+            (step>0 && item < stop) || (step<0 && item > stop);
+            item += step) 
+            results.Add(forGet(item));
+        return results;
+        }
+    static public List<int> For<TIn, TOut>( int start, int stop, int step, ForWhereGet<int, int> forWhereGet) {
+        if ((step > 0 && start > stop) || 
+            (step < 0 && start < stop) || step == 0)
+                    throw new IndexOutOfRangeException(string.Format("ForExpr will never terminate; start={0} stop={1} step={2}",start, stop,step));
+                List<int> results = new List<int>();
+                for ( int item = start; 
+                    (step>0 && item < stop) || (step<0 && item > stop);
+                    item += step) {
+            int value;
+            if (forWhereGet(item, out value))
+                results.Add(value);
+        }
+        return results;
+    }
+        
     static private void ProcessGetSliceArgs(int count, ref int? start, ref int? stop, ref int? step) {
         if (start==null)
             start = 0;

Source/BackEndClr/SharpGenerator.cobra

@@ -3110 +3110 @@
     def writeSharpDef(sw as SharpWriter, parens as bool) is override
         # C#:  CobraImp.For(stuff, delegate(x as int) { return x*x })
         # C#:  CobraImp.For(stuff, delegate(x as int) { if (x<0) return x*x; })
-        inType = _what.type.innerType
+        inType = .inferredType #  _what.type.innerType
         outType = _getExpr.type
         sw.write('CobraImp.For<[inType.sharpRef],[outType.sharpRef]>(')
-        _what.writeSharpDef(sw, false)
+        if _stop
+            # C#:  Numeric For Expr CobraImp.For(start, stop, step, delegate(x as int) { return x*x; })
+            _start.writeSharpDef(sw, false)
+            sw.write(', ')
+            _stop.writeSharpDef(sw, false)
+            sw.write(', ')
+            _step.writeSharpDef(sw, false)
+        else
+            _what.writeSharpDef(sw, false)
         sw.write(', ')
         helperName = '_lh_for_[_var.name]_[_varNumber]'
         if _whereExpr is nil

Source/CobraParser.cobra

@@ -2944 +2944 @@
         #   throw FallThroughException(peek)  # make C# code flow analysis happy
         .expect('IN')
         what = .expression
+        if .optional('COLON')
+            # for x in start : stop ...
+            # for x in start : stop : step ....
+            stopExpr = .expression
+            if .optional('COLON')
+                stepExpr = .expression
         if .optional('WHERE')
             whereExpr as Expr? = .expression
             if .optional('GET')
@@ -2953 +2959 @@
         else
             .expect('GET')
             getExpr = .expression
-        return ForExpr(token, nameExpr, what, whereExpr, getExpr)
+        return ForExpr(token, nameExpr, what, stopExpr, stepExpr, whereExpr, getExpr)
 
     def identifierExpr as Expr
         """

Tests/110-basics-two/600-functional/110-for-expr-enumerable.cobra

@@ +1 @@
+# for expression over enumerables
+class ForExprEnum
+    def main is shared
+        
+        a = for i in [1,2,3] get i*10
+        assert a == [10, 20, 30]
+        #print a        
+        
+        b = for j in 'aeiou' get j
+        assert b == [c'a', c'e', c'i', c'o', c'u']
+        #print b
+    
+        c = ['how', 'now', 'brown', 'cow']
+        d = for k in c where k.endsWith('ow') get k
+        assert d == ['how', 'now', 'cow']
+        
+        d = for k in c where not k.endsWith('ow') get k
+        assert d == ['brown']
+        

Tests/110-basics-two/600-functional/111-for-expr-numeric.cobra

@@ +1 @@
+# for expression over numeric range
+class ForExprNum
+    def main is shared
+        
+        a = for i in [1,2,3] get i*10
+        assert a == [10,20,30]
+        #print a        
+        
+        a = for i in 10 get i
+        assert a == [0,1,2,3,4,5,6,7,8,9]
+        #print a
+        
+        a = for i in 10 where i>5 get i
+        assert a == [6,7,8,9]
+        #print a
+    
+    
+        max = 20
+        am = for i in max where i>15 get i
+        assert am == [16,17,18,19]
+
+        b = for i in 3:6 get i
+        assert b == [3,4,5]
+        #print b
+
+        b = for i in 3:6 where i>=4 get i+1
+        assert b == [5,6]
+        #print b
+        
+    
+        c = for i in 3:6:2 get i
+        assert c == [3,5]
+        #print c
+
+        c = for i in 3:8:2 where i>=4 get i+1
+        assert c == [6,8]
+        #print c
+        
+        
+        c = for i in 3:8:5 where i>=4 get i-10
+        assert c == []
+        #print c
+        
+        c = for i in 8:5:-1 get i
+        assert c == [8,7,6]
+        #print c
+        
+        c = for i in 8:5:-2 get i
+        assert c == [8,6]
+    
+        for i in 8:5:-1
+            print i
+        for i in 8:5:-2
+            print i
+
+        # Non terminating
+        expect IndexOutOfRangeException
+            d = for j in 8:5 get i
+            CobraCore.noOp(d)
+            
+        # Non terminating
+        expect IndexOutOfRangeException
+            d = for j in 5:8:-1 get i
+            CobraCore.noOp(d)
+

Developer/IntermediateReleaseNotes.text

@@ -235 +235 @@
 * Fixed: Cannot use `for` expressions on non-generic enumerables. ticket:85
 
 * Fixed: Cannot `listen` to an event when the `ref`ed method is an overload.
+
+* Fixed: for-expr enumerate int and slice-like range: ticket:71