Ticket #88: UseArray-HowTo.patch

HowTo/160-UseArrays.cobra

@@ +1 @@
+"""
+    Show how to declare and use array variables, literals and sized arrays
+"""
+
+class ArraysExample
+    shared
+     
+        def sum(nums as int[]) as int  # nums arg is array of int
+            test 
+                # Dynamic typing
+                # Inferred array type: assign from array literal; 
+                # Array literal like list (enclosed in [] ) but prefixed by @
+                nums = @[1,2,3] 
+                assert nums.length == 3
+                assert nums[2] == 3 
+                assert ArraysExample.sum(nums) == 6
+                
+                # inferred array type: generate a 'blank' array.
+                # assign from explicitly sized array constructor
+                lottaNums = int[](10)
+                # Array contents are inited to 'default value' for the type (0 in this case)
+                # Generally a specifically sized array is made by assignment from an arrayType constructor
+                # The very general format is
+                # <var-name> = <type>(<args>)
+                # and in the case of arrays, the type is an array type (suffixed by "[]")
+                # and the arg is the desired size or length of the array,
+                # so the array allocation form is:
+                # <var-name> = <type>[](<length>)
+                # e.g nums = number[](100)
+                assert lottaNums.length == 10
+                assert lottaNums[9] == 0
+                assert ArraysExample.sum(lottaNums) == 0 
+
+                # Explicit typing
+                # Init to a blank array
+                nottaLottaNums as int[] = int[](2)
+                assert nottaLottaNums.length == 2
+                assert ArraysExample.sum(nottaLottaNums) == 0 
+                nottaLottaNums[0] = 10
+                nottaLottaNums[1] = 11
+                assert ArraysExample.sum(nottaLottaNums) == 21 
+
+                # another example
+                n = 1024
+                ch = char[](n)
+                for i in n, ch[i] = c'z'
+
+            body 
+                sum = 0 
+                for num in nums 
+                    sum += num
+                return sum 
+            
+        def main 
+            # example passing array to .Net library method
+            # .Net String.split() expects an array of chars
+            parts = 'a|b:c'.split(@[c'|', c':']) 
+            assert parts.length == 3 
+            for part in parts 
+                assert part in ['a','b','c']
+                
+            
+class BinaryFileReader 
+    is abstract
+    """
+    Abstract class that shows array handling for .Net binary file API
+    Reads a file in 256 byte chunks. 
+    Subclass and define handleBuf to provide content handling
+    """
+    shared
+        var stdin = 'stdin'
+
+    var _fileName as String
+
+    def init(fileName as String)
+        _fileName = fileName
+        
+    def readBinaryFile
+        if _fileName == .stdin
+            br = BinaryReader(Console.openStandardInput)
+            _readFile(br)
+            return
+            
+        if not File.exists(_fileName)
+            print "No File: [_fileName]"
+            return
+            
+        #br = BinaryReader(File.open(_fileName, FileMode.Open))
+        br = BinaryReader(FileStream(_fileName, FileMode.Open,FileAccess.Read))
+        _readFile(br)
+    
+    def _readFile(br as BinaryReader)
+        buffer as Byte[] = Byte[](256) # Byte array initialised to blank 256 element array. 
+        #buffer as Byte[] = sharp'new Byte[256]' # alternative using C# fallthrough
+
+        fofset=0
+        nRead = br.read(buffer, 0, 256)
+        while nRead > 0     
+            .handleBuf(buffer, nRead, fofset)
+            fofset += nRead
+            nRead = br.read(buffer, 0, 256)
+        .fileEnd(fofset)    
+        br.close
+            
+    
+    def handleBuf( buffer as Byte[], nRead as int, fOffset as int)  is abstract
+        """ 
+        Called on each filled or partially filled buffer
+        """
+
+    def fileEnd(fOffset as int) is abstract
+        """ 
+        Called on eof before file closed
+        """
+